;; pro dispcomp

;  routine to display comparision of EIT and PEPPI images,
;  and ratio between them.


;goto, bypass


; FIRST, EIT DATA
; retrieve the eit data
restore,'/swing/d/lites/eclipse98/eit/eit_spole_195.save'
;  select frame at 18:13:26 UT
tmpa = a(*,*,4)
nxe = sizeof(tmpa,1) & nye = sizeof(tmpa,2)

;  generate the radial enhancement factor of r^14
;  for eit image
gencompeit,nxe,nye,rad

;  get average background counts at bottom of image
ttt = tmpa(*,2:10)
medfilt,ttt,3,4,ttb
wwh = where(ttb ne 0)
totb = total(ttb(wwh))/float(n_elements(wwh))
tmpa = tmpa-totb

;  enhance corona
tot = total(tmpa(2:201,2:81))/float(200*80)
tmpa = tmpa*rad/tot
;  apply median filter
medfilt,tmpa,4,2.5,tmpc
tmpc = tmpc*100.

;  insert into larger image format for comparison
eitim = fltarr(500,400)
eitim(*,*) = -5000.
eitim(10:10+nxe-1,70:70+nye-1) = tmpc(*,*)
;  shift eit image to compensate for upwards movement
;  of unrotated PEPPI image
eitim = shift(eitim,-4,31)
eitim(6:6+nxe-1,101:104) = -5000.	;  get rid of spurious data at bottom



;  NEXT, PEPPI DATA
;  generate the radial enhancement function for PEPPI data,
;  based on the inferred limb position for EIT data, appropriately
;  shifted, uses an r^7 enhancement function
gencpeppi,500,400,10-4,70+31,radpep

;  retrieve the peppi data
restore,'/swing/d/lites/eclipse98/peppi/sh_genseq10raw.save'
;  select observation for PEPPI
kk=5
pep = avimg(*,*,kk)
nxx = sizeof(pep,1) & nyy = sizeof(pep,2)
;  enhance the image in the radial direction
pepim = fltarr(500,400)
pepim(*,*) = 0
pepim(110:110+nxx-1,66:66+nyy-1) = pep(*,*)
pepim = rot(pepim,-25.)
pepim = pepim*radpep
ppp = bytscl(pepim)

;  pixel shift in horizontal,  best shift seems to be 36 from
;  trial and error
jsh = 36
;  shift in vertical
vsh = -10
pepmm = shift(pepim,jsh,vsh)



;  calculate byte images for display
bpraw = bytscl(pepmm<15000)
whrp = where(bpraw eq 0) & bpraw(whrp) = 255
beraw = bytscl(eitim<4000.)>(-3000.)
whre = where(eitim eq -5000.) & beraw(whre) = 255

;  find overlap where two images are non-zero
whr = where(pepmm gt 0 and eitim gt 0)
ratio = pepim & ratio(*,*) = 0.
ratio(whr) = pepmm(whr)/eitim(whr)
brat = bytscl(ratio,min=-2.,max=10.)
whr = where(brat eq min(brat)) & brat(whr) = 0

;  set backgrounds to zero
bpraw(whrp) = 0 & beraw(whre) = 0


save,filename='SAVE_SET/dispcomp.save',beraw,bpraw,brat,pepmm,eitim,nxe,nye

;bypass: restore,'SAVE_SET/dispcomp.save'

;  pixel coordinates of pentagon defining region common
;  to both PEPPI and EIT images, starting at upper left
;  corner
xpent = [214,325,325,172,120,214]
ypent = [260,260,105,105,215,260]






;  setup image stuff
;  new value of image scale from fitting limb of sun, assuming
;  the standard mean solar radius
;mmpx = 2.518/959.63
;  actual solar radius at the time of the eclipse
mmpx = 2.518/969.27
 
;  sizes in solar radii for plotting window:  sets relative scaling of axes
;  adjust for scaling of window to 8.5 x 11 sheet
;  set for landscape mode
;xsz= 2.
;ysz=2.*8.5/11.
;  set for portrait mode
factr = 8.5/11.
xsz= 2.*factr
ysz=2.
 
;offsets of first image in window, in Mm
xoff = 0.12/xsz
yoff = 0.03/ysz
 
 
;  space in x between panels
xdel = .03
;  space in y between panels
ydel = .03
 




;  now start postscript stuff
;  set character, line thickness
thick = 7.
!x.thick=thick
!y.thick=thick
charthick = 1.5
;
;	Set the device type to high-resolution PostScript.
;
set_plot, 'ps'
;  set for landscape mode
; device, bits_per_pixel=8, file='aapeppi1.ps', scale_factor=1.0, /inches, $
;       xoffset=0.0, yoffset=11.0, ysize=8.5, xsize=11.0, /landscape,color=0
;  set for portrait mode
device, /color, $
	bits_per_pixel=8, file='dispcomp.ps', scale_factor=1.0, /inches, $
        xoffset=0.0, yoffset=0.0, xsize=8.5, ysize=11.0
 
;  set background
dumy = bytarr(85,110) & dumy(*,*) = 0
tv, dumy, 0., 0., xsize=1., ysize=1., /normal

loadct,17
 
;  get dimensions of images
nx = sizeof(pepmm,1)
ny = sizeof(pepmm,2)
; limit of range in x-, y-dimension
xdim = float(nx)*mmpx
ydim = float(ny)*mmpx
;  ranges of arrays
range1 = [ [0., xdim] , [0.,ydim] ]
;  sizes of images in normalized coordinates
xsiz = xdim/xsz
ysiz = ydim/ysz

;
 
;  dummy xyouts to set font
xyouts,.5,.5,'!17 ',charsize=1.5, $
        charthick=3.0, /normal,color=254



;  Upper display: PEPPI intensity
x_im1_p1 = xoff
y_im1_p1 = yoff -.1 + 1.*(ydel + ysiz)
x_im1_p2 = x_im1_p1 + xsiz
y_im1_p2 = y_im1_p1 + ysiz
tv, bpraw, x_im1_p1, y_im1_p1, xsize=xsiz, ysize=ysiz, /normal
plot,xpent,ypent, /noerase, /ynozero, /normal,  $
	xstyle=5,ystyle=5, $
	xrange = [0,(nx-1)], yrange = [0.,(ny-1)], color=255, $
        position=[x_im1_p1, y_im1_p1, x_im1_p2, y_im1_p2]

;  label image
xyouts,x_im1_p1+.00,y_im1_p2-.17, $
	'!17PEPPI Image, Radially Enhanced: (r/R!l!9n!n!17)!u7!n',charsize=1.5, $
        charthick=3.0, /normal,color=254


;  label columns
xyouts,x_im1_p1+.00,y_im1_p2-.03, $
	'!17HAO/NCAR PEPPI', $
		charsize=1.8, charthick=3.0, /normal, color = 255
xyouts,x_im1_p1+.3,y_im1_p2-.03, $
	'!17(Photometric Eclipse Polar Plume Imager)', $
		charsize=1.4, charthick=3.0, /normal, color = 255
xyouts,x_im1_p1+.01,y_im1_p2-.06, $
	'!17Curacao, Netherlands Antilles, 26 February 1998',charsize=1.8, $
        charthick=3.0, /normal, color = 255
;  add squiggle below c in curacao
xyouts,x_im1_p1+.12,y_im1_p2-.06, $
	'!9s!17',charsize=0.7, charthick=3.0, /normal,orientation=180., color = 255
xyouts,x_im1_p1+.00,y_im1_p2-.10, $
	'!17SOHO EIT', $
		charsize=1.8, charthick=3.0, /normal, color = 255
xyouts,x_im1_p1+.16,y_im1_p2-.10, $
	'!17(Extreme ultraviolet Imaging Telescope)', $
		charsize=1.4, charthick=3.0, /normal, color = 255






;  Middle display: EIT image
;  size of array to plot
nx = 325+1
ny = 260-105+1
; limit of range in x-, y-dimension
xdim = float(nx)*mmpx
ydim = float(ny)*mmpx
;  sizes of images in normalized coordinates
xsiz = xdim/xsz
ysiz = ydim/ysz

x_im1_p1 = xoff
y_im1_p1 = yoff + 1.1*(ydel + ysiz)
x_im1_p2 = x_im1_p1 + xsiz
y_im1_p2 = y_im1_p1 + ysiz
tv, beraw(0:325,105:260),x_im1_p1,y_im1_p1,xsize=xsiz,ysize=ysiz,/normal

plot,xpent,ypent-105, /noerase, /ynozero, /normal,  $
	xstyle=5,ystyle=5, $
	xrange = [0,(nx-1)], yrange = [0,(ny-1)], color=255, $
        position=[x_im1_p1, y_im1_p1, x_im1_p2, y_im1_p2]

;  label image
xyouts,x_im1_p2+.01,y_im1_p2-.03,'!17SOHO-EIT Fe XII 195 A',charsize=1.5, $
        charthick=3.0, /normal,color=254
xyouts,x_im1_p2+.01,y_im1_p2-.06, $
	'!17Radially Enhanced:',charsize=1.5, $
        charthick=3.0, /normal,color=254
xyouts,x_im1_p2+.01,y_im1_p2-.09, $
	'!17(r/R!l!9n!n!17)!u14!n',charsize=1.5, $
        charthick=3.0, /normal,color=254




;  Lower display: Ratio of Images
x_im1_p1 = xoff 
y_im1_p1 = yoff + 0.17*(ydel + ysiz)
x_im1_p2 = x_im1_p1 + xsiz
y_im1_p2 = y_im1_p1 + ysiz
; restrict the  imaging range of the ratio image as was
; done for the EIT image
tv, brat(0:325,105:260), x_im1_p1, y_im1_p1, xsize=xsiz, ysize=ysiz, /normal

plot,xpent,ypent-105, /noerase, /ynozero, /normal,  $
	xstyle=5,ystyle=5, $
	xrange = [0,(nx-1)], yrange = [0,(ny-1)], color=255, $
        position=[x_im1_p1, y_im1_p1, x_im1_p2, y_im1_p2]


;  label image
xyouts,x_im1_p2+.01,y_im1_p2-.03,'!17Ratio: PEPPI/SOHO-EIT',charsize=1.5, $
        charthick=3.0, /normal,color=254




device, /close_file
set_plot, 'x'
;
;	Done.





end