;
;  Mauna Loa Image differencing program.
;
;  This widget program operates on two Mauna Loa .slit format images and
;  makes subtractions.  Users can also make measurements of events in the
;  solar corona using this program.
;
;  Drafted by Tony Darnell  26 Nov 1996
;
;  HISTORY:
;
;  9 Dec 96:   Fixed problem with logical unit crashes, added FREE_LUN to
; 		extract procedure.
;  21 Jan 97:  Corrected problem with color table shift when measuring from
;		direct image.
;  8 Aug 97:   Rewrote major portions of code to make program more efficient.
;		Repackaged the widgets in a more user friendly manner.  Changed
;		name from rpB1.pro to df.pro.
;  22 Jan 98:  Added compatability with FITS images.
;  2007-7-9 (sitongia) add SECCHI compatibility.
;
PRO df_event,event

COMMON widgets,back_list,fore_list,meas_window,buttons,path_box,img,image, $
  filelist,backimg,foreimg,hdu1,hdu2,text_array,minslider,data_box,  $
  maxslider,months,time1,time2,direct_flag,back_hdu,fore_hdu,ext, $
  meas_array,numpress,buttons2,forefile,err_buttons,dfit,fit,ltest, $
  plot1,plot2,plot3,plot_info,exten,exten_b,filepath,panel3,xcenter,ycenter

CASE event.id OF
    
    back_list:BEGIN             ;{
        WIDGET_CONTROL,path_box,GET_VALUE=path
                                ;IF (STRMID(path,STRLEN(path)-1,1) NE '/') THEN path=path+'/'
        path=path+'/'
        backfile=filelist(event.index)
        time1=STRMID(backfile,7,2)+':'+STRMID(backfile,10,2)
                                ;CATCH,file_err
                                ;IF (file_err NE 0) THEN BEGIN
                                ;  junk=WIDGET_MESSAGE(!ERR_STRING,/ERROR,TITLE='Bummer')
                                ;  RETURN
                                ;ENDIF
        ext=STRMID(backfile,STRLEN(backfile)-3,3)
        pre=STRMID(backfile,0,3)
        IF (ext EQ 'lit') THEN BEGIN
            close,1
            openr,1,backfile
            readu,1,backimg
            close,1
        ENDIF
        IF (ext EQ 'fts') OR (ext EQ '.gz') OR (pre EQ 'ecd') THEN BEGIN
            backimg=READFITS(backfile,back_hdu)
            ;backimg=rfits(backfile,header=back_hdu)

                                ;Modify header for STEREO data
            obs=fxpar(back_hdu,'OBSRVTRY')
            obs_err=!err
            IF (obs_err NE -1) THEN BEGIN
                IF (STRCMP(obs,'STEREO',6)) THEN BEGIN
                    fxaddpar,back_hdu,'TELESCOP',obs
                    datetime=fxpar(back_hdu,'DATE-OBS')
                    strings=strsplit(datetime,'T',/EXTRACT)
                    fxaddpar,back_hdu,'DATE-OBS',strings[0]
                    fxaddpar,back_hdu,'TIME-OBS',strings[1]
                ENDIF
            ENDIF ELSE BEGIN
                tmp=readfits(backfile,exten_b,exten_no=1)
            ENDELSE

            bbso_tst=STRING(fxpar(back_hdu,'ORIGIN'))
            IF (bbso_tst EQ 'BBSO    ') THEN BEGIN
                tmp1=fxpar(back_hdu,'CENX')
                tmp2=fxpar(back_hdu,'CENY')
                fxaddpar,back_hdu,'CRPIX1',tmp1
                fxaddpar,back_hdu,'CRPIX2',tmp2
            ENDIF
        ENDIF

        sz=SIZE(foreimg)
        backsz=SIZE(backimg)
        WIDGET_CONTROL,img,GET_VALUE=img_Id
        WSET,img_Id
        WIDGET_CONTROL,img,DRAW_XSIZE=backsz(1),DRAW_YSIZE=backsz(2)
        WIDGET_CONTROL,minslider,GET_VALUE=mn
        WIDGET_CONTROL,maxslider,GET_VALUE=mx
        IF (sz(1) NE 0) THEN $
          diffimg=BYTSCL(foreimg-backimg,MIN=mn,MAX=mx,TOP=230) $
        ELSE diffimg=backimg
        IF (ext EQ 'lit') THEN $
          diffimg=it_drawcircle(diffimg,/SLIT)
        IF (ext EQ 'fts') OR (ext EQ '.gz') THEN $
          diffimg=it_drawcircle(diffimg,/FTS,HDR=back_hdu)
                                ;dispimg=BYTSCL(diffimg,MIN=mn,MAX=mx,TOP=230)
                                ;tv,dispimg
        TV,diffimg
        WIDGET_CONTROL,back_list,SET_UVALUE=backfile
    END                         ;}

    fore_list:BEGIN             ;{
                                ;dfcol
        minval=-10
        maxval=10
        WIDGET_CONTROL,path_box,GET_VALUE=path
                                ;IF (STRMID(path,STRLEN(path)-1,1) NE '/') THEN path=path+'/'
        path=path+'/'
        forefile=filelist(event.index)
                                ;CATCH,file_err
                                ;IF (file_err NE 0) THEN BEGIN
                                ;  junk=WIDGET_MESSAGE(!ERR_STRING,/ERROR,TITLE='Bummer')
                                ;  RETURN
                                ;ENDIF
        ext=STRMID(forefile,STRLEN(forefile)-3,3)
        pre=STRMID(forefile,0,3)
        IF (ext EQ 'lit') THEN BEGIN
            close,1
            openr,1,forefile
            readu,1,foreimg
            close,1
        ENDIF
        IF (ext EQ 'fts') OR (ext EQ '.gz') OR (pre EQ 'ecd') THEN BEGIN
            foreimg=READFITS(forefile,fore_hdu)
            ;foreimg=rfits(forefile,header=fore_hdu)

            lasco_test=STRCOMPRESS(fxpar(fore_hdu,'INSTRUME'),/REMOVE_ALL)
            l_sz=SIZE(foreimg)
            IF (lasco_test EQ 'LASCO') AND (l_sz(1) EQ 512) THEN BEGIN
                new_platescl=FLOAT(fxpar(fore_hdu,'PLATESCL'))*2
                fxaddpar,fore_hdu,'PLATESCL',new_platescl
            ENDIF

                                ;Modify header for STEREO data
            obs=fxpar(fore_hdu,'OBSRVTRY')
            obs_err=!err
            IF (obs_err NE -1) THEN BEGIN
                IF (STRCMP(obs,'STEREO',6)) THEN BEGIN
                    fxaddpar,fore_hdu,'TELESCOP',obs
                    datetime=fxpar(fore_hdu,'DATE-OBS')
                    strings=strsplit(datetime,'T',/EXTRACT)
                    fxaddpar,fore_hdu,'DATE-OBS',strings[0]
                    fxaddpar,fore_hdu,'TIME-OBS',strings[1]
                ENDIF
            ENDIF ELSE BEGIN
                tmp=readfits(forefile,exten,exten_no=1)
            ENDELSE

            bbso_tst=STRING(fxpar(fore_hdu,'ORIGIN'))
            IF (bbso_tst EQ 'BBSO    ') THEN BEGIN
                tmp1=fxpar(fore_hdu,'CENX')
                tmp2=fxpar(fore_hdu,'CENY')
                fxaddpar,fore_hdu,'CRPIX1',tmp1
                fxaddpar,fore_hdu,'CRPIX2',tmp2
            ENDIF
        ENDIF

        WIDGET_CONTROL,xcenter,SET_VALUE=fxpar(fore_hdu,'CRPIX1')
        WIDGET_CONTROL,ycenter,SET_VALUE=fxpar(fore_hdu,'CRPIX2')
        WIDGET_CONTROL,img,GET_VALUE=img_Id
        WSET,img_Id
        WIDGET_CONTROL,minslider,GET_VALUE=mn
        WIDGET_CONTROL,maxslider,GET_VALUE=mx
        sz=SIZE(foreimg)
        IF (sz(1) NE 0) THEN $
          diffimg=BYTSCL(foreimg-backimg,MIN=mn,MAX=mx,TOP=230) $
        ELSE diffimg=backimg
        IF (ext EQ 'lit') THEN $
          diffimg=it_drawcircle(diffimg, /SLIT)
        IF (ext EQ 'fts') OR (ext EQ '.gz') THEN $
          diffimg=it_drawcircle(diffimg,/fts,HDR=fore_hdu)
        IF (pre EQ 'ecd') THEN $
          diffimg=BYTSCL((foreimg-backimg)>minval<maxval)
                                ;dispimg=BYTSCL(diffimg,MIN=mn,MAX=mx,TOP=230)
                                ;tv,dispimg
        TV,diffimg
        WIDGET_CONTROL,back_list,GET_UVALUE=backfile
        IF (ext EQ 'lit') THEN $
          df_annotate,forefile,backfile
        IF (ext EQ 'fts') OR (ext EQ '.gz') THEN BEGIN
            df_annotate,forefile,backfile, $
              img=diffimg,hdr1=back_hdu,hdr2=fore_hdu
        ENDIF
        WIDGET_CONTROL,fore_list,SET_UVALUE=forefile
        direct_flag = 0
    END                         ;}

    minslider:BEGIN
        WIDGET_CONTROL,minslider,GET_VALUE=mn
        WIDGET_CONTROL,minslider,SET_VALUE=mn
        IF (direct_flag EQ 1) THEN BEGIN
            WIDGET_CONTROL,maxslider,GET_VALUE=mx
            WIDGET_CONTROL,back_list,GET_UVALUE=backfile
            WIDGET_CONTROL,fore_list,GET_UVALUE=forefile
            TV,BYTSCL(foreimg,MIN=mn,MAX=mx)
            df_annotate,forefile,backfile,/no_minus
        ENDIF 
    END

    maxslider:BEGIN
        WIDGET_CONTROL,maxslider,GET_VALUE=mx
        WIDGET_CONTROL,maxslider,SET_VALUE=mx
        IF (direct_flag EQ 1) THEN BEGIN
            WIDGET_CONTROL,minslider,GET_VALUE=mn
            WIDGET_CONTROL,back_list,GET_UVALUE=backfile
            WIDGET_CONTROL,fore_list,GET_UVALUE=forefile
            TV,BYTSCL(foreimg,MIN=mn,MAX=mx)
            df_annotate,forefile,backfile,/no_minus
        ENDIF 
    END

    img:BEGIN                   ;{
        x=event.x
        y=event.y
        button_press=event.press
        button_release=event.release
        hdrsz1=SIZE(back_hdu)
        hdrsz2=SIZE(fore_hdu)
        mk3rad=104.4435
        IF (hdrsz1(1) NE 0) THEN $
          radius1=it_getrad(back_hdu)
        xcen=fxpar(fore_hdu,'CRPIX1')
        ycen=fxpar(fore_hdu,'CRPIX2')
        IF (hdrsz2(1) NE 0) THEN BEGIN
            radius2=it_getrad(fore_hdu)
            xcen=fxpar(fore_hdu,'CRPIX1')
            ycen=fxpar(fore_hdu,'CRPIX2')
        ENDIF

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;  Set center according to fits format
        xcen=xcen-1.
        ycen=ycen-1. 
; do not change for MK4 (still old format)
        IF (fxpar (back_hdu, 'TELESCOP') EQ 'Mk4') THEN BEGIN
            xcen=xcen+1.
            ycen=ycen+1. 
        ENDIF

        IF (radius1 NE 0) THEN rad=radius1 $
        ELSE rad = mk3rad
        IF (radius2 NE  0) THEN rad=radius2 $
        ELSE rad = mk3rad
        IF (ext EQ 'lit') THEN BEGIN
            rad=mk3rad
            xcen=255.5
            ycen=255.5
        ENDIF
        acirc=!PI * 2.0/360.0
        xdis=xcen-x & xdissq=xdis*xdis
        ydis=ycen-y & ydissq=ydis*ydis
        radius=SQRT(xdissq+ydissq)/rad
                                ;
                                ; Correct for geometric distortions in LASCO images
                                ;
        IF (strcompress(fxpar(fore_hdu,'INSTRUME'),/remove_all) eq 'LASCO') THEN $
          BEGIN
            data = SQRT(xdissq+ydissq)
            mm = data * 0.021
            if (strcompress(fxpar(fore_hdu,'DETECTOR'),/remove_all) eq 'C2') THEN $
              BEGIN
                cf = DISTORTION_COEFFS('C2') ;gets coeffs in millimeters
                radius = mm*(cf[0]+cf[1]*mm^2+cf[2]*mm^4)
                radius = data + radius / 0.021 ;converts back to pixels
            ENDIF
            if (strcompress(fxpar(fore_hdu,'DETECTOR'),/remove_all) eq 'C3') THEN $
              BEGIN
                cf = DISTORTION_COEFFS('C3') ;gets coeffs in millimeters
                radius = mm*(cf[0]+cf[1]*mm^2)
                radius = data + radius/0.021 ;converts back to pixels
            ENDIF
            radius = radius / rad ;convert from pixels to solar radii
        ENDIF
        theta=(ATAN(ydis,xdis)/acirc) + 90
        IF (fxpar(fore_hdu,'TELESCOP') EQ 'DPM     ') THEN $
          IF (fxpar(fore_hdu,'CROTA1') NE 0) THEN $
          theta = theta - (fxpar(fore_hdu,'SOLAR_P0'))
        IF (theta LT 0.) THEN theta=theta+360
        IF (theta GT 360.) THEN theta=theta-360
        text_array(0,*)='x=      '+STRING(x)
        text_array(1,*)='y=      '+STRING(y)
        text_array(2,*)='Radius= '+STRING(radius)
        text_array(3,*)='Theta=  '+STRING(theta)
        WIDGET_CONTROL,ltest,SET_VALUE=text_array[2]+'  '+text_array[3]

        IF (button_press NE 0) THEN BEGIN ;{
            
            meas={data}         ;automatically create data structure
            temp=fxpar(fore_hdu,'DATE-OBS')
            meas.date_str=temp
                                ;  get the date right, everyone is doing it differently
            date=FIX(STR_SEP(temp,'/'))
            err_flg=SIZE(date)
            IF (err_flg[1] LT 3) THEN date=FIX(STR_SEP(temp,'-'))

            IF (fxpar(fore_hdu,'TELESCOP') EQ 'DPM     ') THEN BEGIN
                                ;doy=julday(date(1),date(0),date(2))-julday(12,31,date(2)-1) 
                doy=julday(date(1),date(2),date(0))-julday(12,31,date(0)-1) 
                meas.date_str=STRING(date(1),date(2),date(0),  $
                                     FORMAT="(i2.2,'/',i2.2,'/',i4.2)")
            ENDIF ELSE $
              IF (fxpar(fore_hdu,'TELESCOP') EQ 'MK3     ') THEN BEGIN
                doy=julday(date(1),date(0),date(2))-julday(12,31,date(2)-1) 
                meas.date_str=STRING(date(1),date(0),date(2),  $
                                     FORMAT="(i2.2,'/',i2.2,'/',i2.2)")
            ENDIF ELSE $
              IF (fxpar(fore_hdu,'TELESCOP') EQ 'SOHO    ') THEN BEGIN
                                ;doy=julday(date(1),date(0),date(2))-julday(12,31,date(2)-1)
                doy=julday(date(1),date(2),date(0))-julday(12,31,date(0)-1)
                
                year=strcompress(STRING(date[0]),/REMOVE_ALL)
                year=STRMID(year,2,2)
                meas.date_str=STRING(date(1),date(2),year, $
                                     FORMAT="(i2.2,'/',i2.2,'/',i2.2)") 
                                ;meas.date_str=STRING(date(1),date(2),date(0), $
                                ;	FORMAT="(i2.2,'/',i2.2,'/',i2.2)")
            ENDIF ELSE BEGIN
                doy=julday(date(1),date(2),date(0))-julday(12,31,date(0)-1)
                tmp=STRCOMPRESS(STRING(date(0)),/REMOVE_ALL)
                date(0)=FIX(STRMID(tmp,2,2))
                meas.date_str=STRING(date(1),date(2),date(0),  $
                                     FORMAT="(i2.2,'/',i2.2,'/',i2.2)")
            ENDELSE
            meas.dataset=STRCOMPRESS(fxpar(fore_hdu,'TELESCOP'),/REMOVE_ALL)
            meas.doy=doy
            IF (meas.dataset EQ 'SOHO') THEN $
              meas.dataset=STRCOMPRESS(fxpar(fore_hdu,'DETECTOR'),/REMOVE_ALL)
            IF (fxpar(fore_hdu,'TELESCOP') EQ 'MK3     ') THEN BEGIN
                slitname=STRMID(forefile,0,STRLEN(forefile)-4)
                                ; There are two versions for findtime, one for SUN and another
                                ; for SGI.  Determine opsys and run correct version.
                spawn,'uname -s',opsys
                IF (opsys(0) EQ 'IRIX') THEN BEGIN
                    spawn,'/opt/share/PUBLIC/bin.IRIX/findtime -a ' $
                      +STRCOMPRESS(theta)+' '+slitname,tmp
                    temp=STRMID(tmp[3],STRLEN(tmp[3])-11,11)
                ENDIF ELSE BEGIN
                    spawn,'/home/cordyn/mk3/findtime -a ' $
                      +STRCOMPRESS(theta)+' '+slitname,tmp
                    temp=STRMID(tmp[3],STRLEN(tmp[3])-11,11)
                ENDELSE
                                ;End of findtime section.
            ENDIF ELSE $
              temp=fxpar(fore_hdu,'TIME-OBS')
            IF (STRCMP(fxpar(fore_hdu,'TELESCOP'),'Mk4',3,/FOLD_CASE)) THEN $
            temp=findtime(fore_hdu,exten,theta)
            meas.time_str=temp
            IF (fxpar(fore_hdu,'TELESCOP') EQ 'MK3     ') THEN $
              time=FLOAT(STR_SEP(temp,'_')) ELSE $
              time=FLOAT(STR_SEP(temp,':'))
            mins=(time[0]*60)+(time[1])+(time[2]/60)

                                ;
                                ;==== Check to see if measurements go into the next day
                                ;     add 1440 if true.
                                ;
            IF (numpress GT 0) THEN $
              IF ((mins LT 1440.) AND (doy GT meas_array[0].doy)) THEN $
              mins=mins+1440.0	; 1440 minutes in a day

            meas.mins=mins
            meas.radius=radius
            meas.theta=theta
            meas.x=x
            meas.y=y
            meas.xcen=xcen
            meas.ycen=ycen
            meas.time_str=STRING(time(0),time(1),time(2), $
                                 FORMAT="(i2.2,':',i2.2,':',i2.2)")
            IF (time(0) GT 24) THEN meas.doy=meas.doy+1
            IF (button_press EQ 1) THEN meas.feature = 'LOOP'
            IF (button_press EQ 2) THEN meas.feature = 'CAVITY'
            IF (button_press EQ 4) THEN meas.feature = 'CORE'
                                ;WIDGET_CONTROL,err_buttons,GET_VALUE=test
            WIDGET_CONTROL,err_buttons,GET_VALUE=test
            meas.error=test
                                ;IF (test EQ 0) THEN meas.error=0.03
                                ;IF (test EQ 1) THEN meas.error=0.05
                                ;IF (test EQ 2) THEN meas.error=0.06
                                ;IF (test EQ 3) THEN meas.error=0.07
                                ;IF (test EQ 4) THEN meas.error=0.08
                                ;IF (test EQ 5) THEN meas.error=0.09
                                ;IF (test EQ 6) THEN meas.error=0.10
                                ;IF (test EQ 7) THEN meas.error=0.12
                                ;IF (test EQ 8) THEN meas.error=0.15

            meas_array[numpress]=meas
            meas_array[numpress].time=meas_array[numpress].mins

            datanum=STRTRIM(STRING(numpress+1),1)
            datanum=datanum+' '
            datastr=STRING(datanum,meas.dataset,meas.feature,meas.doy,meas.time_str, $
                           meas.radius,meas.theta,meas.x,meas.y,meas.xcen,meas.ycen, $
                           FORMAT="(A3,A5,A8,I5,A12,F10.4,F10.2,F10.2,F10.2,F10.2,F10.2)")
            WIDGET_CONTROL,data_box,SET_VALUE=datastr,/APPEND
            numpress=numpress+1
            sz=SIZE(meas_array)
            IF (numpress GT sz(1)) THEN numpress = 0
        ENDIF                   ;}

                                ;WIDGET_CONTROL,meas_window,SET_VALUE=text_array
    END                         ;}

    data_box:BEGIN              ;{
        WIDGET_CONTROL,data_box,GET_VALUE=tmp
        IF (event.type EQ 3) THEN BEGIN
            t=WIDGET_INFO(data_box,/TEXT_SELECT)
            index=WIDGET_INFO(data_box,TEXT_OFFSET_TO_XY=t[0])
            meas_str=tmp[index[1]]
            meas_str=STRCOMPRESS(STRTRIM(meas_str,2))
            tmp_meas=STR_SEP(meas_str,' ')
            tmp_numpress=FIX(tmp_meas[0])-1
            tmp_dataset=STRCOMPRESS(tmp_meas[1],/REMOVE_ALL)
            tmp_feature=STRCOMPRESS(tmp_meas[2],/REMOVE_ALL)
            tmp_doy=STRCOMPRESS(tmp_meas[3],/REMOVE_ALL)
            tmp_timestr=STRCOMPRESS(tmp_meas[4],/REMOVE_ALL)
            tmp_radius=FLOAT(tmp_meas[5])
            tmp_theta=FLOAT(tmp_meas[6])
            meas_array[tmp_numpress].dataset=tmp_dataset
            meas_array[tmp_numpress].feature=tmp_feature
            meas_array[tmp_numpress].doy=tmp_doy
            meas_array[tmp_numpress].time_str=tmp_timestr
            meas_array[tmp_numpress].radius=tmp_radius
            meas_array[tmp_numpress].theta=tmp_theta
        ENDIF
    END                         ;}

    err_buttons:BEGIN           ;{
    END                         ;}

    xcenter:BEGIN               ;{
        WIDGET_CONTROL,xcenter,GET_VALUE=xcen
        fxaddpar,fore_hdu,'CRPIX1',xcen+1.
    END                         ;}

    ycenter:BEGIN
        WIDGET_CONTROL,ycenter,GET_VALUE=ycen
        fxaddpar,fore_hdu,'CRPIX2',ycen+1.
    END

    path_box:BEGIN              ;{
        WIDGET_CONTROL,path_box,GET_VALUE=newpath
        WIDGET_CONTROL,/HOURGLASS
        newpath=newpath[0]
        len=STRLEN(newpath)-1
        IF (STRPOS(newpath,'/',len) NE -1) THEN  $
          newpath=STRMID(newpath,0,len)
        test=chk_dir(newpath)
        IF (test EQ 1) THEN BEGIN
            CD,newpath
            filelist=file_list(newpath,fltr,/CD)
            filelist=strip_dirname(filelist)
            path=newpath+'/'
            WIDGET_CONTROL,fore_list,SET_VALUE=filelist
            WIDGET_CONTROL,back_list,SET_VALUE=filelist
        ENDIF
    END                         ;}

    buttons:BEGIN               ;{
        CASE event.value OF     ;{
            'Quit':BEGIN
                numpress=0
                meas_array.radius=0.0
                meas_array.mins=0.0
                meas_array.dataset=''
                meas_array.time=''
                meas_array.doy=0
                meas_array.error=0.0
                SPAWN,'\rm /tmp/idlC*.ps'
                WIDGET_CONTROL,event.top,/DESTROY
            END
            
            'Save as Gif':BEGIN ;{
                final_img=TVRD()
                WIDGET_CONTROL,fore_list,GET_UVALUE=file
                df_savegif,final_img,file
            END                 ;}

            'Save as FTS':BEGIN ;{
                final_img=TVRD()
                WIDGET_CONTROL,fore_list,GET_UVALUE=file
                df_savefts,final_img,file,fore_hdu
            END                 ;}

            'View Direct':BEGIN ;{
                WIDGET_CONTROL,fore_list,GET_UVALUE=filename
                WIDGET_CONTROL,path_box,GET_VALUE=path
                path=path+'/'
                                ;load_lut,'blue_white_cp.lut',mn=0,mx=255
                WIDGET_CONTROL,maxslider,GET_VALUE=mx
                WIDGET_CONTROL,minslider,GET_VALUE=mn
                foreimg=it_drawcircle(foreimg)
                TV,BYTSCL(foreimg,MIN=mn,MAX=mx)
                WIDGET_CONTROL,fore_list,GET_UVALUE=forefile
                WIDGET_CONTROL,back_list,GET_UVALUE=backfile
                                ;df_annotate,forefile,backfile,/no_minus
                direct_flag=1
            END                 ;}

            'COLOR':BEGIN       ;{
                xload
            END                 ;}

            'Difcol':BEGIN      ;{
                dfcol
            END                 ;}

        ENDCASE                 ;}
    END                         ;}

    buttons2:BEGIN              ;{
        CASE event.value OF     ;{
            'Print':BEGIN       ;{
                set_plot,'PS'
                device,/color,/portrait,/inches,xsize=7.0,ysize=7.0,$
                  xoffset=0.5,yoffset=3.5,bits_per_pixel=8,$
                  filename='/tmp/idlC.ps'
                df_fit,meas_array
                device,/CLOSE
                set_plot,'X'
                WIDGET_CONTROL,img,GET_VALUE=img_Id
                WSET,img_Id
            END                 ;}

            'Save Fit':BEGIN    ;{
                                ;filepath='/bail/d/tdarnell/measurements/'
                WIDGET_CONTROL,path_box,GET_VALUE=filepath
                filepath=filepath[0]+'/'
                date=STR_SEP(meas_array[0].date_str,'/')
                yr=STRING(date(2))
                doy=STRCOMPRESS(STRING(meas_array[numpress-1].doy, $
                                       FORMAT="(I3.3)"),/REMOVE_ALL)
                mk3_test=WHERE(meas_array.dataset EQ 'MK3')
                mk4_test=WHERE(meas_array.dataset EQ 'Mk4')
                dpm_test=WHERE(meas_array.dataset EQ 'DPM')
                c2_test=WHERE(meas_array.dataset EQ 'C2')
                c3_test=WHERE(meas_array.dataset EQ 'C3')
                eit_test=WHERE(meas_array.dataset EQ 'FE12')
                loop_test=WHERE(meas_array.feature EQ 'LOOP')
                cav_test=WHERE(meas_array.feature EQ 'CAVITY')
                core_test=WHERE(meas_array.feature EQ 'CORE')
                IF (dpm_test[0] NE -1) THEN tele0=meas_array[dpm_test[0]].dataset $
                ELSE tele0=''
                IF (mk4_test[0] NE -1) THEN tele1=meas_array[mk4_test[0]].dataset $
                ELSE tele1=''
                IF (mk3_test[0] NE -1) THEN tele2=meas_array[mk3_test[0]].dataset $
                ELSE tele2=''
                IF (c2_test[0] NE -1) THEN tele3=meas_array[c2_test[0]].dataset $
                ELSE tele3=''
                IF (c3_test[0] NE -1) THEN tele4=meas_array[c3_test[0]].dataset $
                ELSE tele4=''
                IF (loop_test[0] NE -1) THEN feat1='LOOP' ELSE feat1=''
                IF (cav_test[0] NE -1) THEN feat2='CAV' ELSE feat2=''
                IF (core_test[0] NE -1) THEN feat3='CORE' ELSE feat3=''
                tele=tele0+tele1+tele2+tele3+tele4
                feat=feat1+feat2+feat3
                filename1=yr+'d'+doy+'.'+tele+'.'+feat+'.data'
                IF (dfit EQ 1) THEN $
                  filename2=yr+'d'+doy+'.'+tele+'.'+feat+'.fit1.ps'
                IF (dfit EQ 2) THEN $
                  filename2=yr+'d'+doy+'.'+tele+'.'+feat+'.fit2.ps'
                IF (dfit EQ 3) THEN $
                  filename2=yr+'d'+doy+'.'+tele+'.'+feat+'.fit3.ps'
                df_writefile,meas_array[WHERE(meas_array.mins GE 0)],filepath, $
                  filename1
                                ;set_plot,'PS'
                                ;device,/color,/portrait,/inches,xsize=7.0,ysize=7.0,$
                                ;                    xoffset=0.5,yoffset=3.5,bits_per_pixel=8,$
                                ;                    filename=filepath+filename2
                                ;fit=df_fit(meas_array,dfit)
                                ;device,/CLOSE
                                ;set_plot,'X'
                temp=DIALOG_MESSAGE(filepath+filename1+' has been saved',/INFORMATION)
            END                 ;}

            'New Event':BEGIN   ;{
                meas_array.dataset=''
                meas_array.doy=0
                meas_array.time=-1.0
                meas_array.mins=-1.0
                meas_array.radius=0.0
                meas_array.theta=0.0
                meas_array.feature=''
                meas_array.error=0.0
                meas_array.date_str=''
                meas_array.time_str=''
                numpress=0
                datastr=''
                WIDGET_CONTROL,data_box,SET_VALUE=datastr
            END                 ;}

            'Fit1':BEGIN        ;{
                dfit=1
                                ;filepath='/bail/d/tdarnell/measurements/'
                WIDGET_CONTROL,path_box,GET_VALUE=filepath
                print, filepath
                filepath=filepath[0]+'/'
                print, filepath
                                ;filepath='/tmp/'
                filename2='idlC1.ps'
                set_plot,'PS'
                device,/color,/portrait,/inches,xsize=7.0,ysize=7.0,$
                  xoffset=0.5,yoffset=3.5,bits_per_pixel=8,$
                  filename=filepath+filename2
                fit=df_fit(meas_array,1)
                device,/CLOSE
                set_plot,'X'
                WIDGET_CONTROL,img,GET_VALUE=img_Id
                WSET,img_Id
                spawn,'xv '+filepath+filename2
            END                 ;}

            'Fit2':BEGIN        ;{
                dfit=2
                                ;filepath='/tmp/'
                WIDGET_CONTROL,path_box,GET_VALUE=filepath
                filepath=filepath[0]+'/'
                filename2='idlC2.ps'
                set_plot,'PS'
                device,/color,/portrait,/inches,xsize=7.0,ysize=7.0,$
                  xoffset=0.5,yoffset=3.5,bits_per_pixel=8,$
                  filename=filepath+filename2
                                ;WIDGET_CONTROL,plot1,GET_VALUE=plot_Id
                                ;WSET,plot_Id
                fit=df_fit(meas_array,2)
                device,/CLOSE
                set_plot,'X'
                WIDGET_CONTROL,img,GET_VALUE=img_Id
                WSET,img_Id
                spawn,'xv '+filepath+filename2
            END                 ;}

            'Fit3':BEGIN        ;{
                dfit=3
                                ;filepath='/bail/d/tdarnell/measurements/'
                WIDGET_CONTROL,path_box,GET_VALUE=filepath
                filepath=filepath[0]+'/'
                                ;filepath='/tmp/'
                filename2='idlC3.ps'
                set_plot,'PS'
                device,/color,/portrait,/inches,xsize=7.0,ysize=7.0,$
                  xoffset=0.5,yoffset=3.5,bits_per_pixel=8,$
                  filename=filepath+filename2
                fit=df_fit(meas_array,3)
                device,/CLOSE
                set_plot,'X'
                WIDGET_CONTROL,img,GET_VALUE=img_Id
                WSET,img_Id
                spawn,'xv '+filepath+filename2
            END                 ;}

            'Read File':BEGIN   ;{
                RESTORE,'/project/mlso/idl/df/template.sav'
                WIDGET_CONTROL,path_box,GET_VALUE=filepath
                filepath = filepath[0]+'/'
                                ;file=DIALOG_PICKFILE(PATH='/bail/d/tdarnell/measurements',/READ, $
                                ;	FILTER='*.data')
                file=DIALOG_PICKFILE(PATH=filepath,/READ, $
                                     FILTER='*.data')
                tempdata=READ_ASCII(file,TEMPLATE=dataTemplate)
                sz=SIZE(tempdata.dataset)
                meas_array[numpress:numpress+(sz(1)-1)].dataset=tempdata.dataset
                meas_array[numpress:numpress+(sz(1)-1)].feature=tempdata.feature
                meas_array[numpress:numpress+(sz(1)-1)].radius=tempdata.radius
                meas_array[numpress:numpress+(sz(1)-1)].theta=tempdata.theta
                meas_array[numpress:numpress+(sz(1)-1)].error=tempdata.error
                meas_array[numpress:numpress+(sz(1)-1)].doy=tempdata.doy
                meas_array[numpress:numpress+(sz(1)-1)].time_str=tempdata.time_str
                meas_array[numpress:numpress+(sz(1)-1)].date_str=tempdata.date_str
                meas_array[numpress:numpress+(sz(1)-1)].mins=tempdata.mins
                FOR i=numpress,numpress+(sz(1)-1) DO BEGIN
                    datanum=STRTRIM(STRING(i+1),1)
                    datanum=datanum+' '
                    tempmeas=meas_array
                    IF (meas_array[i].mins LT 1440) THEN $
                      IF (meas_array[i].doy GT meas_array[0].doy) THEN $
                      meas_array[i].mins=meas_array[i].mins+1440
                    datastr=STRING(datanum,tempmeas[i].dataset,tempmeas[i].feature,$
                                   tempmeas[i].doy, tempmeas[i].time_str,tempmeas[i].radius, $
                                   tempmeas[i].theta, $
                                   FORMAT="(A3,A5,A8,I5,A12,F10.2,F10.2)")
                    WIDGET_CONTROL,data_box,SET_VALUE=datastr,/APPEND
                ENDFOR
                numpress=numpress+sz(1)
            END                 ;}

            'Add to DB':BEGIN   ;{
                df_dbadd,meas_array,fit
            END                 ;}
        ENDCASE                 ;}
    END                         ;}

ENDCASE
END


PRO df,minscl=minscl,maxscl=maxscl

COMMON widgets

  ;  Mauna Loa image differencing program.

  IF (NOT(KEYWORD_SET(minscl))) THEN minscl = -1200
  IF (NOT(KEYWORD_SET(maxscl))) THEN maxscl = 1200


  ;
  ;  Initialize vars
  ;
  path=curdir()
  fltr=['*fts','*.gz','*fits','*slit','ecd*']
  ;fltr=['*slit']
  filelist=file_list(path,fltr,/FILE,/CD)
  filelist=strip_dirname(filelist)
  image=intarr(512,512)
  backimg=image
  foreimg=image
  text_array=STRARR(5,20)
  months=['Jan','Feb','Mar','Apr','May','Jun','Jul','Aug','Sep','Oct' $
	,'Nov','Dec']
  direct_flag = 0
  numpress=0
  meas_array=REPLICATE({data},500)
  meas_array.time=-1.0
  meas_array.mins=-1.0
  dfit=1
  ;
  ;  Initialize widgets
  ;
  ;base = WIDGET_BASE(TITLE='Mauna Loa Image Differencing Program',/ROW)
  base = WIDGET_BASE(TITLE='Mauna Loa Image Differencing Program',/COLUMN)
  base1=WIDGET_BASE(base,/ROW,/FRAME)
  panel1=WIDGET_BASE(base1,/COLUMN)
  panel2=WIDGET_BASE(base1,/COLUMN)
  plot_panel=WIDGET_BASE(base,/ROW,/FRAME)

  ;  Load difference color table
  dfcol

  ;
  ;  Change cursor to thin arrow
  ;
      device,$
      cursor_image=$
      [1,63,95,111,119,123,125,254,256,0,0,0,0,11,5,0],$
      cursor_mask=$
      [65025,768,1280,2304,4352,8448,16640,33024,257,258,4,8,16,32,64,128],$
      cursor_xy=[0,15]
      
  WDELETE
  path_box=WIDGET_TEXT(panel1,VALUE=path,/EDITABLE)
  label_panel=WIDGET_BASE(panel1,/ROW)
  file_panel=WIDGET_BASE(panel1,/ROW,/FRAME)
  ;minslider=WIDGET_SLIDER(panel1,MINIMUM=-8000, MAXIMUM=10000, $
	;VALUE=-500,TITLE='MIN')
  minslider=WIDGET_SLIDER(panel1,MINIMUM=minscl, MAXIMUM=maxscl, $
	VALUE=-50,TITLE='MIN',xsize=600)
  ;maxslider=WIDGET_SLIDER(panel1,MINIMUM=-8000, MAXIMUM=10000, $
	;VALUE=500,TITLE='MAX')
  maxslider=WIDGET_SLIDER(panel1,MINIMUM=minscl, MAXIMUM=maxscl, $
	VALUE=50,TITLE='MAX',xsize=600)
  ;l=WIDGET_LABEL(panel1,VALUE='Measurement Window',/ALIGN_CENTER)
  meas_panel=WIDGET_BASE(panel1,/ROW,/FRAME)
  l=WIDGET_LABEL(panel1,VALUE='File Operations')
  button_panel=WIDGET_BASE(panel1,/COLUMN,/FRAME)
  label1=WIDGET_BASE(label_panel,XSIZE=250,YSIZE=20)
  label2=WIDGET_BASE(label_panel,XSIZE=350,YSIZE=20)

  l=WIDGET_LABEL(label1,VALUE='Background Images:')
  back_list=WIDGET_LIST(file_panel,XSIZE=40,YSIZE=5,VALUE=filelist)
  l=WIDGET_LABEL(label2,VALUE='Foreground Images:')
  fore_list=WIDGET_LIST(file_panel,XSIZE=40,YSIZE=5,VALUE=filelist)
  ;meas_window=WIDGET_TEXT(meas_panel,XSIZE=20, YSIZE=4)
  buttons=CW_BGROUP(button_panel,['View Direct','Save as Gif','Save as FTS', $
	'COLOR','Difcol','Quit'] ,/ROW,/RETURN_NAME)
  buttons2=CW_BGROUP(button_panel,['Print','Save Fit','New Event','Fit1', $
	'Fit2','Fit3','Read File','Add to DB'], $
	/ROW,/RETURN_NAME)

  l=WIDGET_LABEL(panel1,VALUE='Data Points')
  data_box=WIDGET_TEXT(panel1,XSIZE=50,YSIZE=6,/SCROLL,/EDITABLE,/ALL_EVENTS)

  l=WIDGET_LABEL(panel2,XSIZE=512,VALUE='Subtracted Image')
  ltest=l
  ;img=WIDGET_DRAW(panel2,COLORS=256,/MOTION_EVENTS,XSIZE=512,YSIZE=512, $
  ;  UVALUE=image,RETAIN=2)
  img=WIDGET_DRAW(panel2,COLORS=256,SCR_XSIZE=550,SCR_YSIZE=550, $
	XSIZE=2100,YSIZE=2100,/SCROLL,/MOTION_EVENTS,/BUTTON_EVENTS,  $
	RETAIN=2,UVALUE=image)
  
  l=WIDGET_LABEL(panel2,VALUE='Error Estimate (Solar Radii)')
  err_buttons=CW_FIELD(panel2,value=0.0,TITLE='Error Est.',/float)
  panel3=WIDGET_BASE(panel2,/ROW)
  xcenter = CW_FIELD(panel3,value=0.0,TITLE='X center',/float,XSIZE=7, $
		/RETURN_EVENTS)
  ycenter = CW_FIELD(panel3,value=0.0,TITLE='Y center',/float,XSIZE=7, $
		/RETURN_EVENTS)
  ;err_buttons=CW_BGROUP(panel2,['0.03','0.05','0.06','0.07','0.08','0.09', $
  ;				'0.10','0.12','0.15'], $
  ;				/ROW,/EXCLUSIVE,/RETURN_NAME,SET_VALUE=1)
  ;plot1=WIDGET_DRAW(plot_panel,XSIZE=256,YSIZE=300,RETAIN=2)
  ;plot2=WIDGET_DRAW(plot_panel,XSIZE=256,YSIZE=300,RETAIN=2)
  ;plot3=WIDGET_DRAW(plot_panel,XSIZE=256,YSIZE=300,RETAIN=2)
  ;plot_info=WIDGET_LABEL(plot_panel,VALUE='Plot Information')

  ;
  ;  Draw widgets
  ;
  WIDGET_CONTROL,base,/REALIZE
  XMANAGER,'df',base

END